Traitement par lot sous Gimp 2.6

J’ai déjà décortiqué un script pour The Gimp. Il s’agit d’un script tout ce qu’il y a de plus classique : un script qui travaille sur une image ouverte.

Cette fois, je m’attaque à un script de traitement par lot. Sous ce nom barbare se cache la possibilité de faire traiter par The Gimp un répertoire complet sans devoir ouvrir chaque fichier l’un après l’autre.

À qui s’adresse ce billet ?

Avec le traitement par lot, il est possible d’automatiser des tâches que vous effectuez pour chacune de vos photos comme :

• correction automatique,
• application d’un logo,
• ajout d’une bordure,
• redimensionnement,
• etc.

Moyennant une légère modification, le script présenté dans ce billet s’adaptera facilement à vos besoins.

Mais avant de vous lancer à cœur perdu dans son étude, posez-vous la question de savoir si le traitement que vous voulez automatiser n’est pas suffisamment simple pour être traité par une autre solution.

Pour commencer vous pouvez jeter un œil sur :

• le plug-in (pardon greffon) DBP pour The Gimp,
• Phatch Photo batch processor, une application pour Linux.

Si ces solutions ne vous satisfont pas ou si vous avez déjà développé votre propre script et ne voulez pas vous en séparer, n’hésitez pas à poursuivre la lecture de ce billet 😉

Principe

Le script est découpé en trois parties :

• fonction traiter-image : j’ai séparé le traitement d’un fichier en 2, traiter-image est chargée de traiter une seule image ouverte passée en paramètre, cela facilitera l’adaptation de scripts initialement prévus pour ne traiter qu’une seule image,
• fonction traiter-fichier : elle est chargée de traiter un seul fichier, c’est-à-dire d’ouvrir le fichier, de récupérer l’image, de la faire traiter par traiter-image, d’enregistrer les modifications et de fermer le fichier,
• parcours de chaque fichier : cette fonction va générer les noms de fichiers pour ensuite les traiter un à un par la fonction traiter-fichier.

Pour adapter le script à vos besoins, il faudra juste modifier la fonction traiter-image.

Le script

Voici le script au complet.  Les explications et le détail suivent.

Pour rappel, il s’agit de code TinyScheme pour The Gimp.

; Définition des extensions autorisées
(define TRAITEMENTPARLOT-EXTENSIONS
  '("JPG" "jpg" "jpeg" "tif" "xcf" "png")
)

; Fonction de traitement par lot
(define (script-fu-traitementparlot nom-repertoire extension)
  ; Fonction chargée de traiter une image
  (define (traiter-image image)
    ; Démarre un niveau de undo
    (gimp-image-undo-group-start image)

    ; Réduit l'image à 500 pixels de large
    (let* ((old-largeur (car (gimp-image-width  image)))
           (old-hauteur (car (gimp-image-height image)))
           (new-largeur 500)
           (new-hauteur (/ (* old-hauteur new-largeur) old-largeur))
          )
      (gimp-image-scale image new-largeur new-hauteur)
    )

    ; Termine le niveau de undo
    (gimp-image-undo-group-end image)
  )

  ; Fonction chargée de traiter un fichier
  (define (traiter-fichier nom-fichier)
    ; Ouverture du fichier
    (let* ((image  (car (gimp-file-load RUN-NONINTERACTIVE nom-fichier nom-fichier)))
           (calque (car (gimp-image-get-active-drawable image)))
          )
      ; Traitement de l’image
      (traiter-image image)

      ; Enregistrement du fichier
      (gimp-file-save RUN-NONINTERACTIVE image calque nom-fichier nom-fichier)

      ; Fermeture du fichier
      (gimp-image-delete image)
    )
  )

  (let* ((extension (list-ref TRAITEMENTPARLOT-EXTENSIONS extension))
         (pattern   (string-append nom-repertoire "/*." extension))
         (fichiers  (cadr (file-glob pattern 0)))
        )
    ; Application de la fonction traiter-fichier à chaque fichier
    (map traiter-fichier fichiers)
  )
)

(script-fu-register "script-fu-traitementparlot"
  "/Script-Fu/Traitement par lot"
  "Exemple de traitement par lot"
  "Frédéric Bisson "
  "Frédéric Bisson"
  "2010-04-20"
  ""
  SF-DIRNAME "Répertoire à traiter" ""
  SF-OPTION "Extension" TRAITEMENTPARLOT-EXTENSIONS
)

Explications du code

Définition des extensions autorisées

Le script nécessite de connaître les extensions de fichiers à traiter. Elles sont définies en tout de début de script sous la constante TRAITEMENTPARLOT-EXTENSIONS. Attention : sous Linux, les extensions sont sensibles à la casse, d’où le JPG et jpg. S’il vous manque une extension, libre à vous de l’ajouter !

(define TRAITEMENTPARLOT-EXTENSIONS
  '("JPG" "jpg" "jpeg" "tif" "xcf" "png")
)

Squelette de la fonction

La fonction principale est la fonction script-fu-traitementparlot qui prend en paramètre un nom de répertoire ainsi que l’index de l’extension sélectionnée parmi celles autorisées (voir ci-dessus).

Script-fu-traitementparlot définit 2 sous-fonctions présentées dans “Principe”.

Pour adapter ce script à vos besoins, il faudra insérer du code entre gimp-image-undo-group-start et gimp-image-undo-group-end.

(define (script-fu-traitementparlot nom-repertoire extension)
  (define (traiter-image image)
    (gimp-image-undo-group-start image)
    ; Traitement de l’image…
    (gimp-image-undo-group-end image)
  )

  (define (traiter-fichier nom-fichier)
    ; …
  )

  (let* ((extension (list-ref TRAITEMENTPARLOT-EXTENSIONS extension))
         (pattern   (string-append nom-repertoire "/*." extension))
         (fichiers  (cadr (file-glob pattern 0)))
        )
    (map traiter-fichier fichiers)
  )
)

Traitement d’un fichier

La fonction traiter-fichier prend comme seul paramètre le chemin complet vers un fichier. La fonction gimp-file-load va ouvrir le fichier sans afficher la moindre fenêtre (RUN-NONINTERACTIVE). Si vous voyez 2 fois le paramètre nom-fichier, rassurez-vous, vous n’avez pas bu, c’est juste nécessaire pour que The Gimp puisse ouvrir des fichiers à travers le réseau (ce qui n’est pas notre cas).

On récupére ensuite un calque de cette image uniquement pour satisfaire une exigence de gimp-file-save bien qu’il ne s’en serve pas…

Une fois ces informations récupérées, on peut lancer le traitement à proprement parler.

La fonction gimp-file-save va permettre de sauvegarder l’image.

Attention : le comportement retenu est celui d’écraser le fichier original, à vous de dupliquer le répertoire sur lequel travailler pour ne pas perdre vos originaux !

On ferme finalement l’image avec la fonction gimp-image-delete. Oui, tout est normal, cette fonction ne va pas supprimer votre fichier mais seulement les informations contenues en mémoire par The Gimp, ce qui revient à fermer le fichier.

(define (traiter-fichier nom-fichier)
  (let* ((image  (car (gimp-file-load RUN-NONINTERACTIVE nom-fichier nom-fichier)))
         (calque (car (gimp-image-get-active-drawable image)))
        )
    (traiter-image image)
    (gimp-file-save RUN-NONINTERACTIVE image calque nom-fichier nom-fichier)
    (gimp-image-delete image)
  )
)

Parcours de répertoire

Le parcours de répertoire est un peu plus sioux que le reste.

Tout d’abord on récupère l’extension. The Gimp nous fournit l’index de l’extension dans la liste des extensions autorisées. La fonction list-ref permet de récupérer un élément dans une liste. En PHP on écrirait “$extension=TRAITEMENTPARLOT_EXTENSIONS[$extension]”, mais on est en TinyScheme…

Il nous faut ensuite un pattern (ex. : /home/user/Images/*.JPG) qui permettra de récupérer les fichiers. Il s’obtient en concaténant le nom de répertoire et l’extension.

Pour obtenir la liste des fichiers, The Gimp dispose d’un plug-in standard appelé file-glob qui travaille sur le pattern précédemment présenté.

La fonction map permet alors d’exécuter la fonction traiter-fichier avec chacun des fichiers trouvés par file-glob. C’est un équivalent de boucle for qui parcourrait la liste des fichiers.

(let* ((extension (list-ref TRAITEMENTPARLOT-EXTENSIONS extension))
       (pattern   (string-append nom-repertoire "/*." extension))
       (fichiers  (cadr (file-glob pattern 0)))
      )
  (map traiter-fichier fichiers)
)

Déclaration de la fonction

La déclaration mérite quelques mots. Tout d’abord, on ne spécifie aucun type de fichier puisqu’elle n’est pas destinée à être exécutée sur une image préalablement ouverte (chaîne vide après la date).

Ensuite on utilise le type de paramètre SF-DIRNAME pour demander à The Gimp d’afficher un widget permettant de sélectionner un répertoire. Il retournera une chaîne avec le chemin complet.

Enfin, le paramètre SF-OPTION permet d’obtenir une combo-box avec la liste des extensions autorisées. Il retournera l’index de l’extension sélectionnée (0 pour la première, 1 pour la deuxième etc.)

(script-fu-register "script-fu-traitementparlot"
  "/Script-Fu/Traitement par lot"
  "Exemple de traitement par lot"
  "Frédéric Bisson "
  "Frédéric Bisson"
  "2010-04-20"
  ""
  SF-DIRNAME "Répertoire à traiter" ""
  SF-OPTION "Extension" TRAITEMENTPARLOT-EXTENSIONS
)

Utilisation

Le script est utilisable tel quel mais ne présente pas un intérêt particulier. Il redimensionne chaque image proportionnellement pour qu’elles aient une largeur de 500 pixels.

Une fois installé, une nouvelle entrée vient prendre place dans le menu Script-Fu :

Menu

En sélectionnant cette entrée dans le menu, la fenêtre de paramètres apparaît avec la possibilité de sélectionner un dossier existant ainsi qu’une extension :

Fenêtre de paramètres

Quand on clique sur le bouton “Valider”, la fenêtre est utilisée pour afficher le traitement en cours :

Traitement en cours